# Budding yeast model (MBC 2000) using WinPP

dCLN2/dt  = (ksn2'+ ksn2"*SBF)*MASS - kdn2*CLN2
dCLB2T/dt = (ksb2'+ ksb2"*MCM)*MASS - Vdb2*CLB2T
dCLB5T/dt = (ksb5'+ ksb5"*SBF)*MASS - Vdb5*CLB5T
dSIC1T/dt = (ksc1'+ ksc1"*SWI) - (kd1c1 + Vd2c1/(Jd2c1+SIC1T))*SIC1T
dC2/dt    = kasb2*CLB2*SIC1 - (kdib2 + Vdb2 + kd1c1 + Vd2c1/(Jd2c1+SIC1T))*C2

dC5/dt    = kasb5*CLB5*SIC1 - (kdib5 + Vdb5 + kd1c1 + Vd2c1/(Jd2c1+SIC1T))*C5
dCDC20T/dt  = (ks20' + ks20"*CLB2) - kd20*CDC20T 
dCDC20/dt  = ka20*(CDC20T-CDC20) - (Vi20 + kd20)*CDC20
dHCT/dt = (kat1'+kat1"*CDC20)*(1-HCT)/(Jat1+1-HCT)-Vit1*HCT/(Jit1+HCT)
dMASS/dt = mu*MASS

dORI/dt  = ksori*(CLB5 + eorib2*CLB2) - kdori*ORI  
dBUD/dt  = ksbud*(CLN2 + CLN3 + ebudb5*CLB5) - kdbud*BUD
dSPN/dt  = ksspn*CLB2/(Jspn+CLB2) - kdspn*SPN
dVi20/dt = 0

BB(Va,Vi,Ja,Ji)= Vi-Va+Ja*Vi+Ji*Va
GK(Va,Vi,Ja,Ji)= 2*Ji*Va/(BB(Va,Vi,Ja,Ji)+sqrt(BB(Va,Vi,Ja,Ji)^2-4*(Vi-Va)*Ji*Va))

CLB2 = CLB2T - C2
CLB5 = CLB5T - C5
SIC1 = SIC1T - C2 -C5
BCK2 = BCK0*MASS
CLN3 = CLN3MAX*Dn3*MASS/(Jn3+Dn3*MASS)

SBF =  GK(Vasbf, kisbf'+kisbf"*CLB2, Jasbf, Jisbf)
MCM =  GK(kamcm*CLB2, kimcm, Jamcm, Jimcm)
SWi =  GK(kaswi*CDC20, kiswi'+kiswi"*CLB2, Jaswi, Jiswi)

Vdb2 = kdb2'*(1-HCT) + kdb2"*HCT +kdb2p*CDC20
Vdb5 = kdb5'+ kdb5"*CDC20
Vd2c1= kd2c1*(ec1n3*CLN3+ec1k2*BCK2+CLN2+ec1b5*CLB5+ec1b2*CLB2)
Vit1 = kit1'+ kit1"*(CLN3 + eit1n2*CLN2 + eit1b5*CLB5 + eit1b2*CLB2)
Vasbf =kasbf*(CLN2+esbfn3*(CLN3+BCK2)+esbfb5*CLB5)

global +1 {ORI-1} {Vi20=ki20"}
global +1 {SPN-1} {Vi20=ki20'}
global -1 {CLB2-Thres1} {MASS=f*MASS; BUD=0; SPN=0}
global -1 {CLB2+CLB5-Thres} {ORI=0}

param  BCK0=0.0027,  CLN3MAX=0.02, Dn3=1
param  ksn2'=0,      ksn2"=0.05,   kdn2=0.1
param  ksb2'=0.002,  ksb2"=0.05,   kdb2'=0.01, kdb2"=2,  kdb2p=0.05
param  ksb5'=0.006,  ksb5"=0.02,   kdb5'=0.1,  kdb5"=0.25
param  ksc1'=0.02,   ksc1"=0.1,    kd1c1=0.01, kd2c1=0.3
 
param  kasb2=50,     kdib2=0.05,   kasb5=50,   kdib5=0.05
param  ks20'=0.005,  ks20"=0.06,   kd20=0.08
param  ka20=1,       ki20'=0.1,    ki20"=10

param  kat1'=0.04,   kat1"=2 
param  kit1'=0,      kit1"=0.64 
param  ksori=2,      kdori=0.06
param  ksbud=0.3,    kdbud=0.06
param  ksspn=0.08,   kdspn=0.06

param  kasbf=1,      kisbf'=0.5,   kisbf"=6
param  kamcm=1,      kimcm=0.15
param  kaswi=1,      kiswi'=0.3,   kiswi"=0.2

param  Jn3=6,       Jd2c1=0.05 
param  Jat1=0.05,   Jit1=0.05,     Jspn=0.2
param  Jasbf=0.01,  Jisbf=0.01,    Jamcm=1,    Jimcm=1 
param  Jaswi=0.1,   Jiswi=0.1

param  ec1n3=20,    ec1k2=2,       ec1b5=1,    ec1b2=0.067
param  eit1n2=1,    eit1b5=0.5,    eit1b2=1
param  eorib2=0.4,  ebudb5=1
param  esbfn3=75,   esbfb5=0.5
param  mu=0.005776, f=0.433,       Thres1=0.3, Thres=0.2
init CLN2=0.0078, CLB2T=0.2342, CLB5T=0.0614, SIC1T=0.1231  
init C2=0.0790, C5=0.0207, CDC20T=0.8332, CDC20=0.6848, HCT=0.9946
init MASS=0.6608, ORI=0, Bud=0, SPN=0, Vi20=0.1

aux CLB5=CLB5
aux SIC1=SIC1
@ Maxstore=100000
@ Meth=Stiff, total=500, xplot=t, xlo=0, xhi=500, ylo=0, yhi=2
@ NPLOT=7, yp1=MASS, yp2=CLB2T, yp3=CLB5T, yp4=Cdc20, yp5=CLN2, yp6=SIC1T, yp7=HCT

done